home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 004 / mathstat.arc / NCCLSPRE.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1983-02-02  |  1.9 KB  |  72 lines
  1. 5  CLS:KEY OFF
  2. 10  REM PRECISION PROGRAM v1.83 by N. ADAMS
  3. 20  REM This program will calculate within run,run to run, and day to day
  4. 30  REM precision.
  5. 32  CLEAR
  6. 34  INPUT "Title: ";TI$
  7. 35  INPUT "Enter number of days of data collected ";N
  8. 40  OPTION BASE 1
  9. 50  DIM A(N,4),B(N,2),C(N,4),D(N),E(N,2),G(N)
  10. 60  PRINT "ENTER EACH DAYS VALUES AS FOLLOWS:"
  11. 70  PRINT "RUN 1 VALUE 1,RUN 1 VALUE 2,RUN 2 VALUE 1, RUN 2 VALUE 2"
  12. 80  FOR I =1 TO N:INPUT "DATA ";A(I,1),A(I,2),A(I,3),A(I,4)
  13. 90  NEXT I
  14. 100  FOR I =1 TO N:
  15. 110        B(I,1) = (A(I,1) + A(I,2))/2
  16. 120        B(I,2) = (A(I,3) + A(I,4))/2
  17. 130  NEXT I
  18. 140  FOR I = 1 TO N:
  19. 150        C(I,1) = (A(I,1) - B(I,1))^2
  20. 160        C(I,2) = (A(I,2) - B(I,1))^2
  21. 170        C(I,3) = (A(I,3) - B(I,2))^2
  22. 180        C(I,4) = (A(I,4) - B(I,2))^2
  23. 190  NEXT I
  24. 200  S=0
  25. 210  FOR I = 1 TO N:
  26. 220  FOR J = 1 TO 4:
  27. 230     S = S+C(I,J)
  28. 240  NEXT J
  29. 250  NEXT I
  30. 260  WR = S/(2*N)
  31. 265  WRP = SQR(WR)
  32. 270  PRINT "WITHIN RUN PRECISION = ",WRP
  33. 280  FOR I = 1 TO N: D(I) = (B(I,1) + B(I,2))/2
  34. 290  NEXT I
  35. 300  T = 0
  36. 310  FOR I = 1 TO N:
  37. 320       E(I,1) = (B(I,1) - D(I))^2
  38. 330       E(I,2) = (B(I,2) - D(I))^2
  39. 340  T = T + E(I,1) + E(I,2)
  40. 350  NEXT I
  41. 360  RR = (2*T)/N
  42. 365  RRP = (RR-WR)/2 :QW = SQR(RRP)
  43. 370  PRINT:PRINT "RUN TO RUN PRECISION = ",QW
  44. 380  L = 0
  45. 390  FOR I = 1 TO N:L = L + D(I)
  46. 400  NEXT I
  47. 410  F = L/N
  48. 420  H = 0
  49. 430  FOR I = 1 TO N:
  50. 440       G(I) = (D(I) - F)^2
  51. 450  H = H + G(I)
  52. 460  NEXT I
  53. 470  PR = (4*H)/(N-1)
  54. 475  PRP = (PR-RR)/4 :ZW =SQR(PRP)
  55. 480  PRINT :PRINT "DAY TO DAY PRECISION = ",ZW
  56. 485  LPRINT TI$:LPRINT
  57. 490  LPRINT SPC(20) "RUN 1" SPC(25) "RUN 2"
  58. 495  LPRINT "DAY","REP 1","REP 2","REP 1","REP 2"
  59. 500  FOR I = 1 TO N:
  60. 510  LPRINT I,A(I,1),A(I,2),A(I,3),A(I,4)
  61. 520  NEXT I
  62. 530  LPRINT:LPRINT:LPRINT
  63. 600  LPRINT: LPRINT:LPRINT
  64. 610  LPRINT "THE WITHIN RUN PRECISION = ";WRP
  65. 620  LPRINT:LPRINT "THE RUN TO RUN PRECISION = ";QW
  66. 630  LPRINT:LPRINT "THE DAY TO DAY PRECISION = ";ZW
  67. 635  PRINT :PRINT
  68. 640  PRINT:INPUT "Continue (C) or End (E): ";ZX$
  69. 650  IF ZX$ = "C" OR ZX$ ="c" THEN 10 ELSE 660
  70. 660  IF ZX$ ="e" OR ZX$ = "E" THEN 700 ELSE 640
  71. 700  CLS: KEY ON
  72.